load("@npm//@angular/build-tooling/bazel/api-golden:index.bzl", "api_golden_test_npm_package")
load("@npm//@bazel/jasmine:index.bzl", "jasmine_node_test")
load("//tools:defaults.bzl", "pkg_npm", "ts_library")

# Copyright Google Inc. All Rights Reserved.
#
# Use of this source code is governed by an MIT-style license that can be
# found in the LICENSE file at https://angular.dev/license
package(default_visibility = ["//visibility:public"])

licenses(["notice"])

# @angular-devkit/core

ts_library(
    name = "core",
    package_name = "@angular-devkit/core",
    srcs = glob(
        include = ["src/**/*.ts"],
        exclude = [
            "src/**/*_spec.ts",
        ],
    ),
    data = glob(
        include = ["**/*.json"],
        # NB: we need to exclude the nested node_modules that is laid out by yarn workspaces
        exclude = [
            "node_modules/**",
            "src/workspace/json/test/**",
        ],
    ),
    module_name = "@angular-devkit/core",
    module_root = "src/index.d.ts",
    deps = [
        "@npm//@types/node",
        "@npm//@types/picomatch",
        "@npm//ajv",
        "@npm//ajv-formats",
        "@npm//jsonc-parser",
        "@npm//picomatch",
        "@npm//rxjs",
        "@npm//source-map",
        # @node_module: typescript:es2015.proxy
        # @node_module: typescript:es2015.reflect
        # @node_module: typescript:es2015.symbol.wellknown
        # @typings: source_map
    ],
)

# @external_begin

ts_library(
    name = "core_test_lib",
    testonly = True,
    srcs = glob(["src/**/*_spec.ts"]),
    data = glob(["src/workspace/json/test/**/*.json"]),
    deps = [
        ":core",
        "//packages/angular_devkit/core/node",
        "@npm//rxjs",
    ],
)

jasmine_node_test(
    name = "core_test",
    srcs = [":core_test_lib"],
)

genrule(
    name = "license",
    srcs = ["//:LICENSE"],
    outs = ["LICENSE"],
    cmd = "cp $(execpath //:LICENSE) $@",
)

pkg_npm(
    name = "npm_package",
    tags = ["release-package"],
    deps = [
        ":README.md",
        ":core",
        ":license",
        "//packages/angular_devkit/core/node",
        "//packages/angular_devkit/core/node/testing",
    ],
)

api_golden_test_npm_package(
    name = "core_api",
    data = [
        ":npm_package",
        "//goldens:public-api",
    ],
    golden_dir = "angular_cli/goldens/public-api/angular_devkit/core",
    npm_package = "angular_cli/packages/angular_devkit/core/npm_package",
    types = ["@npm//@types/node"],
)
# @external_end